Wyo VB Lecture Notes

Objective #1: Write Boolean expressions.

• A Boolean expression is one that simplifies to either True or False. Boolean expressions are named after George Boole, a mathematician and logician in the early Twentieth Century who provided key knowledge to the logic and binary system that is used in modern computers.
  
  
• An example of a Boolean expression is    x < 10   where x is a variable that stores a value. If that value is less than 10, then the Boolean expression simplifies to True. If that value is not less than 10, then the Boolean expression simplies to False.
  
  
• Boolean expressions are created with relational operators and logical operators.
  
  
• The relational operators are:
  
  

  >	greater than
  <	less than
  >=	greater than or equal to
  <=	less than or equal to
  =	equal to
  <>	not equal to

  
  
• When string values are compared with relational operators, VB compares the strings based on their character Unicode values (formerly known as ASCII values). The Unicode value of an uppercase 'A' is 65, the Unicode value of an uppercase 'B' is 66, and so on. Therefore, 'A' is considered to be less than 'B'. In fact, the word 'Apple' is considered to be less than the word 'Banana' since a character by character comparison is performed and the uppercase A in Apple is compared against the uppercase B in Banana. The Unicode value of a lowercase 'a' is 97, the Unicode value of a lowercase 'b' is 98, and so on. Therefore, the word "Zebra" is considered to be less than the word "aardvark" since the Unicode value for uppercase 'Z' is less than the Unicode value of lowercase 'a'. In fact, any word that begins with an uppercase letter is less than any word that begins with a lowercase letter.
  
  Look up "ASCII chart" or "Unicode chart" in Google or refer to the Unicode chart in our classroom for other character Unicode values.
  
  
• The logical operators (sometimes called Boolean operators) are:
  

  And......
  Or.......
  Not

• Use the following truth table to remember how to evaluate the logical operators.
  
  

  A	B	And	Or
  0	0	0	0
  0	1	0	1
  1	0	0	1
  1	1	1	1

  
  
  Notice that the And logical operation is similar to mathematical multiplication since 0 * 0 = 0, 0 * 1 = 0, etc.
  Notice that the Or logical operation is similar to mathematical addition since 0 + 0 = 0, 0 + 1 = 1, etc.
  
  
• You evaluate a Boolean expression just as an algebraic expression. Work left to right and follow the order of operations. Often Boolean expressions contain a mix of relational, logical, and arithmetic operators. Be careful to observe the correct order of operations.
  
  

  Order of Operations

  Arithmetic

  Exponentiation ( ^ )

  Negation ( - )

  *, /

  Mod

  +, -

  Relational

  =, <>, <, >, <=, >=

  Logical

  Not

  And

  Or

  
  
  
• Examples of Boolean expressions using relational, logical, and arithmetic operators.
  
  Assume that variables x and y have the following values:      x = 1 and y = 13
  

  (x > 0)          evaluates to True since x is greater than 0
  (x <> 1)          evaluates to False since x is not equal to 1
  ((x > 5) Or (y <= 20))          evaluates to True since y is less than or equal to 20 (even though x is not greater than 5)
  ((Not (x = 12)) And (y = 13))          evaluates to True since x is not equal to 12 and y is equal to 13
  

Objective #2: Use If statements to ensure that certain statements are executed only when a given condition applies.

• The If statement (sometimes called an "If Then statement") is very useful to represent "what-if" type scenarios in a computer program's algorithm. The statement works in the same way that you would interpret an if-then scenario using the English language
• The first line of an If statement must start with the keyword If.
• The first line of an If statement must end with the keyword Then.
• One or more statements follow the If Then line. These statements are considered to be the body of the If statement.
• You must type End If as the very last line of the If statement.
• The body of the If statement is indented to make it easier to read and logically understand.
  
  
• Here are some examples of If statements:
  
  Dim intAge As Integer = 14
  
  If (intAge >= 21) Then
       MessageBox.Show("You can vote.")
  End If
  
  If (intAge < 16) Then
       MessageBox.Show("You cannot drive a car.")
  End If
  
  If (intAge >= 13 And intAge <= 19) Then
       MessageBox.Show("You are a teenager.")
  End If
  
  
• The Boolean expression between the If and the Then keywords is called the control expression. If the control expression evaluates to True, then Visual Basic will execute the statement(s) that follow. If the control expression is False, then Visual Basic ignores the body of the If statement. In the following If statement
  
  If (intAge < 17) Then
       MessageBox.Show("You cannot watch movies with an R rating unless you are accompanied by an adult over the age of 21.")
  End If
  
  the control expression is      intAge < 17
  
  Parenthesis are not required to placed around an If statement's control expression but they add to the readability of the code and should be used.
  
  The body of the If statement is the indented statement
  
  MessageBox.Show("You cannot watch movies with an R rating unless you are accompanied by an adult over the age of 21.")
  
  
• One line If statements can be used in VB if the If statement would only have one body statement as in
  
  If (intAge >= 21) Then MessageBox.Show("You can vote.")
  
  Mr. Minich discourages the use of one-line If statements and prefers that all If statements be typed out over multiple lines.
  
  If the If statement has two or more body statements it must be typed out with the End If line coming at the end as in
  
  If (intAge >= 21) Then
       MessageBox.Show("You can vote.")
       MessageBox.Show("You can drink alcohol.")
  End If
  
  
• A common mistake by novice programmers is to use an incorrect version of the If statement like the following:

  If (lengthOfSideA = lengthOfSideB = lengthOfSideC) Then
          MessageBox.Show("equilateral triangle")        
  End If

  The Boolean expression, lengthOfSideA = lengthOfSideB = lengthOfSideC, in the If statement is illegal. That expression must be broken into two or more subexpressions and joined with the logical operator And.  The following statement is correct:

  If ((lengthOfSideA = lengthOfSideB) And (lengthOfSideB = lengthOfSideC)) Then
         MessageBox.Show("equilateral triangle")
  End If
  

• You can nest an If statement inside of a For loop as in the following example which finds the sum of all the even numbers between 2 and 10
  
  For J = 2 To 10
     
      If (J Mod 2 = 0) Then
        MessageBox.Show(J + " is an even number")
      End If
  
  Next
  
  
  
• You can use an Exit For statement to break out of a For loop.
  
  For J = 2 To 10
     
      MessageBox.Show("J = " + J)
  
      If (J = 5) Then
          Exit For
      End If
  
  Next
  
  in this loop, the loop immediately stops iterating when J reaches 5 and J never reaches 10. The Exit For statement is usually placed inside of an If statement which is inside a loop.

Objective #3: Use If Else and If ElseIf statements to select which of two sequences of statements will be executed, depending on whether a given condition is TRUE or FALSE.

• The If Else statement can be used to represent a slightly more complicated scenario than the plain If statement. If the control expression after the If keyword is False, then the statement(s) after the Else keyword is executed. The statement(s) following the Else acts as a default.
• The keyword Else appears on a line by itself and is followed by one or more statements that execute if the If control expression is False.
• Do not forget to type the End If phrase as the last line of an If Else statement. If you forget to do this, it will probably cause a compile error or a logic error which programmers informally call a "dangling else error".
• Example:

  If (intAge >= 13) Then
       MessageBox.Show("You can watch a PG-13 rated movie.")
  Else
       MessageBox.Show("You can not watch a PG-13 rated movie.")
  End if

• The If ElseIf statement can be used to represent even more complicated scenarios.
• The ElseIf keyword must be followed by a control expression (within parenthesis for readability) of its own and the keyword Then.
• Example:

  If (intAge >= 17) Then
       MessageBox.Show("You can watch rated R and rated PG-13 movies.")
  ElseIf (intAge >= 13) Then
       MessageBox.Show("You can only watch rated PG-13 movies.")
  End If

• An Else case may also be used with an If ElseIf statement but it must appear below the ElseIf part. For example,
  
  If (intAge >= 17) Then
       MessageBox.Show("You can watch rated R and rated PG-13 movies.")
  ElseIf (intAge >= 13) Then
       MessageBox.Show("You can only watch rated PG-13 movies.")
  Else
       MessageBox.Show("You can only watch G and PG movies.")
  End If
  
  
• You can use as many ElseIf cases as you need but they must be placed after the If case and above the Else case (if it is used). For example,
  
  If (dblGrade >= 90) Then
     lblGrade.Text = "A"
  ElseIf (dblGrade >= 80) Then
     lblGrade.Text = "B"
  ElseIf (dblGrade >= 70) Then
     lblGrade.Text = "C"
  ElseIf (dblGrade >= 60) Then
     lblGrade.Text = "D"
  Else
     lblGrade.Text = "F"
  End If
   
  Notice the necessary use of the >= (greater than or equal to) operator rather than the > (greater than) operator in the example above since a student who earns a grade of exactly 90% should receive an A.
  
  Visual Basic will evaluate the If ElseIf statement above starting with the If condition. As soon as one of the control expressions is determined to be TRUE, Visual Basic will execute the body statements of that portion of the If ElseIf statement and then skip over the remaining parts. That is, in the example above, Visual Basic would never display both an A and a B in lblGrade.Text.
  
  An experienced programmer however wisely uses the Else portion of an If ElseIf statement in order to make his or her program's logic even better and safer. In the following example, the programmer hopes that the Else portion would never execute but in case of a logic error elsewhere in his/her program, the Else portion will help him/her figure out where a bug occurs in the program.
  
  If (dblGrade >= 90) Then
     MessageBox.Show("A")
  ElseIf (dblGrade>= 80) Then
     MessageBox.Show("B")
  ElseIf (dblGrade>= 70) Then
     MessageBox.Show("C")
  ElseIf (dblGrade>= 60) Then
     MessageBox.Show("D")
  ElseIf (dblGrade>= 0) Then
     lblGrade.Text = "F"
  Else
     lblGrade.Text = "A logic error occurred causing your grade to be less than zero!"
  End If
  
  
• It is necessary to represent the real-life problem accurately in your pseudocode before you choose which of the three forms of the If statements to use in your code. If you are not careful, you will unnecessarily complicate your algorithm (perhaps with an unnecessary If ElseIf statement) or you will not fully portray the scenario that you meant to describe. The grade that you receive for a program will be affected by your choice (and arrangement) of If statements.
  
  
• It is possible and sometimes necessary to nest one If statement within another. An example of nested If statements follows:
  
  If (dblGrade >= 90) Then
  
      If (dblGrade >= 98) Then
          MessageBox.Show("A+")
      Else
          MessageBox.Show("A")
      End If
  
  ElseIf (dblGrade >= 80) Then
     MessageBox.Show("B")
  Else
     MessageBox.Show("C")
  End If
  
  Notice that a whole If Else statement is found within the If portion of the outer If ElseIf statement. Also notice that blank lines are placed above and below the inner If Else statement for increased readability.
  
  
• Do not unnecessarily complicate your program or decrease its readability by using nested If statements when you could have simply used a single If ElseIf statement.

Objective #4: Use the Mod operator to test divisibility.

• From your previous math education, you should be familiar with the following terms that relate to divisibility:
  
  • evenly divisible
    
    Example - 10 is evenly divisible by 2 because 10 divided by 2 leaves a zero remainder
    
    
  • factor
    
    Example - 3 is a factor of 12 and 24 since it is a factor of 12 (3 * 4 = 12) and it is a factor of 24 (3 * 8 = 24)
    
    
  • multiple
    
    Example - 20 is a multiple of 5 since 5 times 4 is 20
    
    
  • divisor
    
    Example - 6 is a divisor of 42 since it divides evenly into 42 (42 divided by 6 leaves a remainder of 0)
    
    
  • prime
    
    Example - 13 is prime since it has no divisors except for itself and 1
    
    
• You can use the Mod operator to determine if one number is evenly divisible by another number. Since Mod returns the remainder when dividing two numbers, if that remainder is zero then the numbers are evenly divisible.
  

  24 is evenly divisible by 6 since 24 Mod 6 = 0
  100 is evenly divisible by 10 since 100 Mod 10 = 0
  8 is evenly divisible by 2 since 8 Mod 2 = 0
  9 is evenly divisible by 3 since 9 Mod 3 = 0
  
  The following statement tests to see if 24 is evenly divisible by the variable num
  
  If (24 Mod num = 0) Then
      MessageBox.Show("yes")
  End If
  

• You can use the Mod operator to determine if one number is a factor of another number. Since Mod returns the remainder when dividing two numbers, if that remainder is zero then the smaller number is a factor of the larger number.
  

6 is a factor of 24 since 24 Mod 6 = 0
10 is a factor of 100 since 100 Mod 10 = 0
2 is a factor of 8 since 8 Mod 2 = 0
3 is a factor of 9 since 9 Mod 3 = 0

The following statement tests to see if 4 is a factor of the variable num

If (num Mod 4 = 0) Then
    MessageBox.Show("yes")
End If

• You can use the Mod operator to determine if one number is a multiple of another number. Since Mod returns the remainder when dividing two numbers, if that remainder is zero then the larger number is a multiple of the smaller number.
  

24 is a multiple of 6 since 24 Mod 6 = 0
100 is a multiple of 10 since 100 Mod 10 = 0
8 is a factor of 2 since 8 Mod 2 = 0
9 is a factor of 3 since 9 Mod 3 = 0

The following statement tests to see if 24 is a multiple of the variable num

If (24 Mod num = 0) Then
    MessageBox.Show("yes")
End If

• You can use the Mod operator to determine if one number is a divisor of another number. Since Mod returns the remainder when dividing two numbers, if that remainder is zero then the smaller number is a divisor of the larger number.
  

  6 is a divisor of 24 since 24 Mod 6 = 0
  10 is a divisor of 100 since 100 Mod 10 = 0
  2 is a divisor of 8 since 8 Mod 2 = 0
  3 is a divisor of 9 since 9 Mod 3 = 0
  
  The following statement tests to see if 3 is a divisor of the variable num
  
  If (num Mod 3 = 0) Then
      MessageBox.Show("yes")
  End If

• When any even number is divided by two, the remainder is zero. In other words, "any even number" Mod 2 = 0    because any even number divided by 2 leaves a remainder of 0. For example,
  
  12 is even since 12 Mod 2 = 0
  54 is even since 54 Mod 2 = 0
  19343432 is even since 19343432 Mod 2 = 0
  
  The following statement tests to see if the variable num is an even number
  
  If (num Mod 2 = 0) Then
      MessageBox.Show("yes")
  End If
  
  
• When any odd number is divided by two, the remainder is one. In other words, "any odd number" Mod 2 = 1    because any odd number divided by 2 leaves a remainder of 1. For example,
  
  13 is odd since 13 Mod 2 = 1
  55 is odd since 55 Mod 2 = 1
  19343431 is odd since 19343431 Mod 2 = 1
  
  To determine if the variable intNum is even or odd, you can use the following If statement
  
  If (intNum Mod 2 = 0) Then
     MessageBox.Show("even")
  Else If (intNum Mod 2 = 1) Then
     MessageBox.Show("odd")
  End If
  
  
• You can use Mod in an If statement to determine if the variable intNum is prime or not.
  
  If (intNum = 2 Or intNum = 3 Or intNum = 5 Or (intNum Mod 2 <> 0 And intNum Mod 3 <> 0 And intNum Mod 5 <> 0)) Then
     MessageBox.Show("prime")
  Else
     MessageBox.Show("not prime")
  End If
  
  Are the extra parentheses in the If statement necessary? This algorithm would correctly test whether any number up to 48 is prime or not. Do you know why?